AC_PREREQ(2.52)

AC_INIT(gpass, 0.5.1, http://projects.netlab.jp/gpass/)
AC_CONFIG_SRCDIR(src/main.c)
AM_INIT_AUTOMAKE(AC_PACKAGE_NAME, AC_PACKAGE_VERSION)

AM_MAINTAINER_MODE
AM_CONFIG_HEADER(config.h)
AM_DISABLE_STATIC

AC_PROG_INTLTOOL([0.31])

AM_PROG_LIBTOOL

AC_ISC_POSIX
AC_PROG_CC
AC_PROG_INSTALL
AC_PROG_MAKE_SET

dnl make sure we keep ACLOCAL_FLAGS around for maintainer builds to work
AC_SUBST(ACLOCAL_AMFLAGS, "$ACLOCAL_FLAGS")

dnl ==================================================================
dnl checks GLib
dnl ==================================================================
PKG_CHECK_MODULES(GLIB, [
    glib-2.0
    gmodule-2.0 
    gthread-2.0 
    gobject-2.0
])
AC_SUBST(GLIB_LIBS)
AC_SUBST(GLIB_CFLAGS)

dnl ==================================================================
dnl checks GNOME Config System
dnl ==================================================================
AC_PATH_PROG(GCONFTOOL, gconftool-2)
AM_GCONF_SOURCE_2
PKG_CHECK_MODULES(GCONF, [
    gconf-2.0
])
AC_SUBST(GCONF_LIBS)
AC_SUBST(GCONF_CFLAGS)

dnl ==================================================================
dnl checks GNOME library
dnl ==================================================================
PKG_CHECK_MODULES(GNOME, [
    libgnomeui-2.0 
    gtk+-2.0 >= 2.4 
    libglade-2.0
])
AC_SUBST(GNOME_LIBS)
AC_SUBST(GNOME_CFLAGS)

dnl ==================================================================
dnl checks Mhash - http://mhash.sourceforge.net/
dnl ==================================================================
AM_PATH_MHASH

dnl ==================================================================
dnl checks Mcrypt - http://mcrypt.hellug.gr/
dnl ==================================================================
AM_PATH_MCRYPT
if test "x$HAVE_MCRYPT" = "xno"; then
    AC_MSG_ERROR(Mcrypt not found)
fi

dnl ==================================================================
dnl checks Check - http://check.sourceforge.net/
dnl set unit test condition
dnl ==================================================================
AM_PATH_CHECK(0.9.2, HAVE_CHECK=yes, HAVE_CHECK=no)
if test "x$HAVE_CHECK" = "xyes"; then
    AC_CHECK_LIBM
    AC_SUBST(LIBM, $LIBM)
fi
AM_CONDITIONAL(WANT_TEST, test "x$HAVE_CHECK" = "xyes")

dnl ==================================================================
dnl Gettext stuff.
dnl ==================================================================
GETTEXT_PACKAGE=gpass
AC_SUBST(GETTEXT_PACKAGE)
AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", 
                   [Package name for gettext])
ALL_LINGUAS="ja da"
AM_GLIB_GNU_GETTEXT

dnl ==================================================================
dnl Set some directory
dnl ==================================================================
dnl Set PACKAGE SOURCE DIR in config.h.
packagesrcdir=`cd $srcdir && pwd`

dnl Set PACKAGE PREFIX
if test "x${prefix}" = "xNONE"; then
    packageprefix=${ac_default_prefix}
else
    packageprefix=${prefix}
fi

dnl Set PACKAGE DATA & DOC DIR
packagedatadir=share/${PACKAGE}
packagedocdir=doc/${PACKAGE}

dnl Set PACKAGE DIRs in config.h.
packagepixmapsdir=share/pixmaps/${PACKAGE}
packagehelpdir=share/gnome/help/${PACKAGE}
packagemenudir=share/gnome/apps

dnl Subst PIXMAPS DIR
PIXMAPS_DIR="${packageprefix}/share/pixmaps"
AC_SUBST(PIXMAPS_DIR)

dnl Subst PACKAGE_DATA_DIR.
NO_PREFIX_PACKAGE_DATA_DIR="${packagedatadir}"
AC_SUBST(NO_PREFIX_PACKAGE_DATA_DIR)
PACKAGE_DATA_DIR="${packageprefix}/${packagedatadir}"
AC_SUBST(PACKAGE_DATA_DIR)

dnl Subst PACKAGE_DOC_DIR.
NO_PREFIX_PACKAGE_DOC_DIR="${packagedocdir}"
AC_SUBST(NO_PREFIX_PACKAGE_DOC_DIR)
PACKAGE_DOC_DIR="${packageprefix}/${packagedocdir}"
AC_SUBST(PACKAGE_DOC_DIR)

dnl Subst PACKAGE_PIXMAPS_DIR.
NO_PREFIX_PACKAGE_PIXMAPS_DIR="${packagepixmapsdir}"
AC_SUBST(NO_PREFIX_PACKAGE_PIXMAPS_DIR)
PACKAGE_PIXMAPS_DIR="${packageprefix}/${packagepixmapsdir}"
AC_SUBST(PACKAGE_PIXMAPS_DIR)

dnl Subst PACKAGE_HELP_DIR.
NO_PREFIX_PACKAGE_HELP_DIR="${packagehelpdir}"
AC_SUBST(NO_PREFIX_PACKAGE_HELP_DIR)
PACKAGE_HELP_DIR="${packageprefix}/${packagehelpdir}"
AC_SUBST(PACKAGE_HELP_DIR)

dnl Subst PACKAGE_MENU_DIR.
NO_PREFIX_PACKAGE_MENU_DIR="${packagemenudir}"
AC_SUBST(NO_PREFIX_PACKAGE_MENU_DIR)
PACKAGE_MENU_DIR="${packageprefix}/${packagemenudir}"
AC_SUBST(PACKAGE_MENU_DIR)

AC_DEFINE_UNQUOTED(PIXMAPS_DIR, "$PIXMAPS_DIR", [Pixmaps install diretory])
AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${packageprefix}/${packagedatadir}",
                   [Data install directory])
AC_DEFINE_UNQUOTED(PACKAGE_DOC_DIR, "${packageprefix}/${packagedocdir}",
                   [Document install directory])
AC_DEFINE_UNQUOTED(PACKAGE_PIXMAPS_DIR, "${packageprefix}/${packagepixmapsdir}", 
                   [Pixmaps install diretory])
AC_DEFINE_UNQUOTED(PACKAGE_HELP_DIR, "${packageprefix}/${packagehelpdir}", 
                   [Help install directory])
AC_DEFINE_UNQUOTED(PACKAGE_MENU_DIR, "${packageprefix}/${packagemenudir}", 
                   [Menu install directory])
AC_DEFINE_UNQUOTED(PACKAGE_SOURCE_DIR, "${packagesrcdir}", 
                   [Source directory])

dnl Set PACKAGE_LOCALE_DIR.
PACKAGE_LOCALE_DIR="${packageprefix}/${DATADIRNAME}/locale"
AC_SUBST(PACKAGE_LOCALE_DIR)
AC_DEFINE_UNQUOTED(PACKAGE_LOCALE_DIR, "${PACKAGE_LOCALE_DIR}",
                   [i18n message catalog install directory])

dnl ==================================================================
dnl create files
dnl ==================================================================
AC_OUTPUT([
Makefile
m4/Makefile
include/Makefile
include/gpass/Makefile
lib/Makefile
src/Makefile
tools/Makefile
po/Makefile.in
data/Makefile
data/gpass.desktop.in
pixmaps/Makefile
doc/Makefile
tests/Makefile
tests/gpass/Makefile
])

dnl ==================================================================
dnl echo result
dnl ==================================================================
echo "
==================================================================
Configuration:

    Source code location : ${srcdir}
    Install location     : ${packageprefix}
    Compiler             : ${CC}
    Unit test(make check): ${HAVE_CHECK}

"